注册 登录  
 加关注
查看详情
   显示下一条  |  关闭
温馨提示!由于新浪微博认证机制调整,您的新浪微博帐号绑定已过期,请重新绑定!立即重新绑定新浪微博》  |  关闭

@从前有个T

weibo.com/sysutt

 
 
 

日志

 
 
 
 

一段很好的控制FLASH中文字滚动的AS代码  

2008-03-14 11:18:46|  分类: FLASH |  标签: |举报 |字号 订阅

  下载LOFTER 我的照片书  |

         把使用方法也加进注释里面了,要用的时候直接拷贝过去就行,为了尊重作者版权,里面的版权声明也保留了。他的个人网站也挺不错的,里面有很多值得一看东西。 制作文字滚动还有其他方法,例如直接在按钮上设置rollover、press、release之类的,不过下面这个会相对简单一些。

 

 

/*
program    : hqlulu
mail    : hqlulu@163.com
website    : http://www.aslibra.com
publish    : 2006-10-31


使用方法:

做两个按钮做滚动:up_btn,down_btn
做遮罩定下显示的范围:mask_mc
移动的mc:move_mc

*/
//判断是否移动
var move_it:Boolean = false;
//移动方向
var dir:Number = 1;
//移动速度
var speed:Number = 1;
//按下的移动速度加倍
var scale:Number = 3;
//滚轮的移动速度加倍
var scale_mouse:Number = 3;
//设置上下的边距
var margin:Number = 2;
//计算移动的范围
var max1:Number = mask_mc._y+margin;
var min1:Number = mask_mc._y-move_mc._height+mask_mc._height-margin;
//是否自动设置遮罩
var is_set_mask:Boolean = false;
//是否支持鼠标
var is_mouse_enable:Boolean = true;
//设置按钮、遮罩和移动的对象
var my_move_mc:MovieClip = move_mc;
var my_up_btn:Button = up_btn;
var my_down_btn:Button = down_btn;
var my_mask_mc:MovieClip = mask_mc;
 

 
//自动调整遮罩的xy和宽
if (is_set_mask) {
    my_mask_mc._x = my_move_mc._x;
    my_mask_mc._y = my_move_mc._y;
    my_mask_mc._width = my_move_mc._width;
    my_move_mc.setMask(my_mask_mc);
}
//支持滚轮移动  
if (is_mouse_enable) {
    var mouseListener:Object = new Object();
    mouseListener.onMouseWheel = function(delta) {
        if (delta>0) {
            my_dir = 1;
        } else {
            my_dir = -1;
        }
        speed *= scale_mouse*scale;
        move_me();
        speed /= scale_mouse*scale;
    };
    Mouse.addListener(mouseListener);
}
//给向上的按钮赋予事件            
my_up_btn.onRollOver = function() {
    move_it = true;
    my_dir = 1;
};
my_up_btn.onRollOut = function() {
    move_it = false;
};
my_up_btn.onPress = function() {
    speed *= scale;
};
my_up_btn.onRelease = function() {
    speed /= scale;
};
my_up_btn.onReleaseOutside = function() {
    speed /= scale;
    move_it = false;
};
//给向下的按钮赋予事件           
my_down_btn.onRollOver = function() {
    move_it = true;
    my_dir = -1;
};
my_down_btn.onRollOut = function() {
    move_it = false;
};
my_down_btn.onPress = function() {
    speed *= scale;
};
my_down_btn.onRelease = function() {
    speed /= scale;
};
my_down_btn.onReleaseOutside = function() {
    speed /= scale;
    move_it = false;
};
//判断是否该移动           
my_move_mc.onEnterFrame = function() {
    if (move_it) {
        move_me();
    }
};
//移动mc           
function move_me() {
    if ((my_move_mc._y+my_dir*speed)>max1) {
        my_move_mc._y = max1;
    } else {
        if ((my_move_mc._y+my_dir*speed)<min1) {
            my_move_mc._y = min1;
        } else {
            my_move_mc._y += my_dir*speed;
        }
    }
}

  评论这张
 
阅读(1100)| 评论(0)
推荐 转载

历史上的今天

评论

<#--最新日志,群博日志--> <#--推荐日志--> <#--引用记录--> <#--博主推荐--> <#--随机阅读--> <#--首页推荐--> <#--历史上的今天--> <#--被推荐日志--> <#--上一篇,下一篇--> <#-- 热度 --> <#-- 网易新闻广告 --> <#--右边模块结构--> <#--评论模块结构--> <#--引用模块结构--> <#--博主发起的投票-->
 
 
 
 
 
 
 
 
 
 
 
 
 
 

页脚

网易公司版权所有 ©1997-2018